data rats;
input diet wt;
d = diet;
cards;
1 20.5
1 23.0
1 26.9
1 26.0
1 23.4
2 38.5
2 40.0
2 40.4
2 39.0
2 40.0
3 43.1
3 46.4
3 48.2
3 46.1
3 45.4
4 45.0
4 47.5
4 50.1
4 49.8
4 48.4
5 46.4
5 47.3
5 48.4
5 45.0
5 45.4
;

proc glm data=rats;
classes Diet;
model wt = Diet;
estimate 'mu+d1' intercept 1 diet 1 0 0 0 0;
estimate 'mu+d2' intercept 1 diet 0 1 0 0 0;
estimate 'mu+d3' intercept 1 diet 0 0 1 0 0;
estimate 'mu+d4' intercept 1 diet 0 0 0 1 0;
estimate 'mu+d5' intercept 1 diet 0 0 0 0 1;
contrast 'Diets' Diet -2 -1 0 1 2,
                 Diet 2 -1 -2 -1 2,
                 Diet -1 2 0 -2 1,
                 Diet 1 -4 6 -4 1;
contrast 'Diets, L+Q' Diet -2 -1 0 1 2,
                      Diet 2 -1 -2 -1 2;
contrast 'Diets, C+Q' Diet -1 2 0 -2 1,
                      Diet 1 -4 6 -4 1;
/* Least Squares Means comparisons using Scheffe's test */
lsmeans Diet/stderr pdiff adjust=scheffe;
/* Least Squares Means comparisons asuming a simple t-test */
lsmeans Diet/stderr pdiff;
run;

proc glm data=rats;
model wt = diet diet*diet diet*diet*diet
		   diet*diet*diet*diet;
run;

proc glm data=rats;
classes Diet;
model wt = d d*d diet;
run;